Parameterization

Parameterization is nothing but giving multiple Input/Test data to the test script.


Different ways to Parameterize:

1.  Input the Test data from External files.

2.  Input the Test data through Datatable.

3.  Input Test data through loop statements.

4.  Input Test data dynamically through interactive submission.


Input the Test data from External files:

Set myxl = createobject("excel.application") 
 
'Make sure that you have created an excel file before executing the script . 
'Use the path of excel file in the below code.
'Also make sure that your excel file is in Closed state.
 
myxl.Workbooks.Open "D:\parameter.xls"
myxl.Application.Visible = true 
 
'"Sheet1" is the name of Sheet in Excel file "qtp.xls" where data needs to be entered .
set mysheet = myxl.ActiveWorkbook.Worksheets("Sheet1")
 
'contents of sheet1
'Uname              Pwd
'------------     ------------
'qtpworld.com       qtp
'admin              qtp
'                   qtp
'admin 
'abcd              abcd
 
'Launch Gmail
Systemutil.Run "iexplore.exe","http:\\www.gmail.com"
 
Browser("title:=Gmail: Email from Google").Page("title:=Gmail: Email from Google").Sync
 
'Get the max row occupied in the excel file 
Row=mysheet.UsedRange.Rows.Count 
 
'To read the data from the entire Excel file
For i= 2 to Row
 
Username=mysheet.cells(i,1).value
Password=mysheet.cells(i,2).value
 
' Enter Email id in Username Field
Browser("title:=Gmail: Email from Google").Page("title:=Gmail: Email from Google").WebEdit("name:=Email").Set Username
 
'Enter password in Passowrd Field
Browser("title:=Gmail: Email from Google").Page("title:=Gmail: Email from Google").WebEdit("name:= Passwd").Set Password
 
wait 1
 
Next
 
'Close the Workbook
myxl.ActiveWorkbook.Close
 
'Close Excel
myxl.Application.Quit
 
'Release the objects
Set mysheet =nothing
Set myxl = nothing

 
 

Input the Test data through Datatable:

'Insert  username and Password in the datatable sheet "Global"   under column  "Username" and "Password" 
 
'contents of  Global Sheet
'Username         Password
'-------------   ------------
'qtpworld.com     qtp
'admin            qtp
'                 qtp
'admin 
'abcd             abcd
 
'Get the max used range of the datasheet "Global"
row=datatable.GetSheet("Global").GetRowCount
 
'Launch gmail.com
Systemutil.Run  "iexplore.exe","http:\\www.gmail.com"
 
Browser("title:=Gmail: Email from Google").Page("title:=Gmail: Email from Google").Sync
 
'Make sure whenever you parameterize through datatable you do the following ,
'1. go to File ->Settings ->Run
'2.On the right side panel , Under  "Data Table iterations"   select the first option that is  "Run one iteration only"
 
'Loop to read all the data in the datasheet "Global"
For   Drow= 1 to row
 
datatable.GetSheet("Global").SetCurrentRow(Drow)
Username=datatable.Value("Username","Global")
Password=datatable.Value("Password","Global")
 
' Enter  Email id in Username Field
Browser("title:=Gmail: Email from Google").Page("title:=Gmail: Email from Google").WebEdit("name:=Email").Set Username
 
'Enter password in Passowrd Field
Browser("title:=Gmail: Email from Google").Page("title:=Gmail: Email from Google").WebEdit("name:= Passwd").Set  Password
 
Wait 1
 
Next

 


Input Test data through loop statements:

'parameterize using loop value
For orderno=1 to 10
 
'Login to sample Qtp flight application and keep the main window open.
Window("Flight Reservation").WinButton("Button").Click
Window("Flight Reservation").Dialog("Open Order").WinCheckBox("Order No.").Set "ON"
 
'Parameterize orderno using the loop value
Window("Flight Reservation").Dialog("Open Order").WinEdit("Edit").Set orderno
Window("Flight Reservation").Dialog("Open Order").WinButton("OK").Click
 
Next

 

Input Test data dynamically through interactive submission:

'Launch gmail.com
Systemutil.Run  "iexplore.exe","http:\\www.gmail.com"
 
Browser("title:=Gmail: Email from Google").Page("title:=Gmail: Email from Google").Sync
 
'Allowing user to enter  User name and  Password  three times during run time
 
For  i = 1 to 3 
 
'Allowing user to enter  User name and  Password
Username=Inputbox("Enter username")
Password=InputBox("Enter Password")
 
' Enter  Email id in Username Field
Browser("title:=Gmail: Email from Google").Page("title:=Gmail: Email from Google").WebEdit("name:=Email").Set Username
 
'Enter password in Passowrd Field
Browser("title:=Gmail: Email from Google").Page("title:=Gmail: Email from Google").WebEdit("name:= Passwd").Set  Password
 
Next